cleo-скрипт. Что не так?

xxxsxxx · 20-07-2008 07:14

Я написал cleo-скрипт, но он почему-то не работает. Но игра запускается. Просто не реагирует на заданную мной команду на key16. Надо, чтоб машина, в какой сидит CJ, взрывалась при нажатии пробел. Посмотрите, плз, что здесь не так:

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007

{$VERSION 3.1.0027}
{$CLEO .cs}

//-------------MAIN---------------
wait 0 

:NONAME_4
wait 0 
if 
   Actor.Driving($PLAYER_ACTOR)
else_jump @NONAME_4 
Car.RemoveReferences($4)
03C0: $4 = actor $PLAYER_ACTOR car 
jump @NONAME_39 

:NONAME_39
wait 0 
if 
   Actor.InCar($PLAYER_ACTOR, $4)
else_jump @NONAME_4 
if 
00E1:   player $PLAYER_ACTOR pressed_key 16 
else_jump @NONAME_39 
Car.Destroy($4)
jump @NONAME_4

Заранее благодарен!

Last edited by xxxsxxx (20-07-2008 07:17)

Seemann · 20-07-2008 07:40

Замени все $4 на 0@.

Этот блок лишний

jump @NONAME_39 

:NONAME_39
wait 0 
if 
   Actor.InCar($PLAYER_ACTOR, $4)
else_jump @NONAME_4

убери его совсем.

{$CLEO} 
0000:
while true
    wait 250
    if
        0256:   player $PLAYER_CHAR defined
    then 
        if and
            Actor.Driving($PLAYER_ACTOR)
            00E1:   player $PLAYER_CHAR pressed_key 16  // accelerate button
        then
            03C0: 0@ = actor $PLAYER_ACTOR car
            020B: explode_car 0@ 
            wait 1000
        end
    end           
end

Last edited by Seemann (20-07-2008 15:01)

xxxsxxx · 20-07-2008 14:46

Чет все равно не отвечает key16...
Так?:

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007

{$VERSION 3.1.0027}
{$CLEO .cs}

//-------------MAIN---------------
wait 0 

:NONAME_4
wait 0 
if 
   Actor.Driving($PLAYER_ACTOR)
else_jump @NONAME_4 
Car.RemoveReferences(0@)
03C0: 0@ = actor $PLAYER_ACTOR car 
while true
    wait 250
    if
        0256:   player $PLAYER_CHAR defined
    then 
        if and
            Actor.Driving($PLAYER_ACTOR)
            00E1:   player $PLAYER_ACTOR pressed_key 16
        then
            03C0: 0@ = actor $PLAYER_ACTOR car
            020B: explode_car 0@
        end
    end           
end

или так

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007

{$VERSION 3.1.0027}
{$CLEO .cs}

//-------------MAIN---------------
wait 0 

:NONAME_4
wait 0 
if 
   Actor.Driving($PLAYER_ACTOR)
else_jump @NONAME_4 
Car.RemoveReferences(0@)
03C0: 0@ = actor $PLAYER_ACTOR car 
jump @NONAME_39 

:NONAME_39
wait 0 
if 
   Actor.InCar($PLAYER_ACTOR, 0@)
else_jump @NONAME_4 
if 
00E1:   player $PLAYER_ACTOR pressed_key 16 
else_jump @NONAME_39 
020B: explode_car 0@
jump @NONAME_4

а может так

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007

{$VERSION 3.1.0027}
{$CLEO .cs}

//-------------MAIN---------------
wait 0 

:NONAME_4
wait 0 
        if
            Actor.Driving($PLAYER_ACTOR)
            00E1:   player $PLAYER_ACTOR pressed_key 16
        then
            03C0: 0@ = actor $PLAYER_ACTOR car
            020B: explode_car 0@
        end
jump @NONAME_4

Но работает никак...

xxxsxxx · 20-07-2008 14:52

Да, и еще... в чем разница между 020B: explode_car и Car.Destroy(0@)?

Seemann · 20-07-2008 15:03

Да, и еще... в чем разница между 020B: explode_car и Car.Destroy(0@)?

020B взрывает машину, а car.destroy просто убирает из игры безо всяких эффектов.

Попробуй еще раз скрипт из второго поста, я профиксил его.
button 16 - это кнопка ускорения.

xxxsxxx · 20-07-2008 16:19

Ага, большое спс! Но возник еще 1 вопрос:
Почему

{$CLEO .cs}

//-------------MAIN---------------
0000: NOP 

:NONAME_2
0001: wait 0 ms 
00D6: if and
00DF:   actor $PLAYER_ACTOR driving 
00E1:   player $PLAYER_CHAR pressed_key 16 
004D: jump_if_false @NONAME_2 
03C0: 0@ = actor $PLAYER_ACTOR car 
020B: explode_car 0@ // versionA 
0001: wait 10000 ms 
0002: jump @NONAME_2

работает, а

{$CLEO .cs}

//-------------MAIN---------------
wait 0

:NONAME_2
0001: wait 0 ms 
00D6: if and
00DF:   actor $PLAYER_ACTOR driving 
00E1:   player $PLAYER_CHAR pressed_key 16 
004D: jump_if_false @NONAME_2 
03C0: 0@ = actor $PLAYER_ACTOR car 
020B: explode_car 0@ // versionA 
0001: wait 10000 ms 
0002: jump @NONAME_2

- нет?

xxxsxxx · 20-07-2008 16:21

Почему нельзя использовать wait 0 вместо 0000: NOP ?

xxxsxxx · 20-07-2008 17:12

Вот опкод "актер в машине":
0449:actor $PLAYER_ACTOR in_a_car
Как задать "если актер НЕ в машине"??

...if
0449:actor $PLAYER_ACTOR in_a_car
then...

flashTrash · 20-07-2008 19:00

Как задать "если актер НЕ в машине"??

"прибавить" восьмёрку - 8449:

xxxsxxx · 23-07-2008 22:24

Посмотрите плз, как эти 3 блока можно обьеденить в один скрипт?:

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007

{$VERSION 3.1.0027}
{$CLEO .cs}

//-------------MAIN---------------
0006: 1@ = 304498 
0006: 2@ = 304498 
0006: 3@ = 304499 

:NONAME_32
0001: wait 0 ms 
00D6: if and
0256:   player $PLAYER_CHAR defined 
0038:   &0(1@,1i) == 255 
004D: jump_if_false @NONAME_32 
00A1: put_actor $PLAYER_ACTOR at 2488.91 -1666.91 13.14 
0001: wait 3000 ms 
0002: jump @NONAME_32

:NONAME_207
0001: wait 0 ms 
00D6: if and
0256:   player $PLAYER_CHAR defined 
0038:   &0(2@,1i) == 16711680 
004D: jump_if_false @NONAME_207 
00A1: put_actor $PLAYER_ACTOR at 2488.91 -1666.91 23.24 
0001: wait 3000 ms 
0002: jump @NONAME_207 

:NONAME_273
0001: wait 0 ms 
00D6: if and
0256:   player $PLAYER_CHAR defined 
0038:   &0(3@,1i) == 255 
004D: jump_if_false @NONAME_273 
00A1: put_actor $PLAYER_ACTOR at 2488.91 -1666.91 33.34 
0001: wait 3000 ms 
0002: jump @NONAME_273

put_actor РАЗНЫЕ!!!

Last edited by xxxsxxx (23-07-2008 22:26)

Fess · 24-07-2008 08:12

@xxxsxxx -

{$CLEO}
0000:
while true
    wait 0
    if
        Player.Defined($PLAYER_CHAR)
    then
        if
            0AB0:  key_pressed 0x74
        then
            Actor.PutAt($PLAYER_ACTOR, 2488.91, -1666.91, 13.14)
            wait 3000
        end
        if
            0AB0:  key_pressed 0x75
        then
            Actor.PutAt($PLAYER_ACTOR, 2488.91, -1666.91, 23.24)
            wait 3000
        end
        if
            0AB0:  key_pressed 0x76
        then
            Actor.PutAt($PLAYER_ACTOR, 2488.91, -1666.91, 33.34)
            wait 3000
        end
    end
end

xxxsxxx · 25-07-2008 06:15

Еще вопрос: можно как-то сделать, чтоб 015D: set_gamespeed влияло только на окружающих(на моего актера не влияло) или наоборот? Может для этого нужен какой-то другой опкод? Или мечтать не вредно?))

3Doomer · 25-07-2008 08:52

xxxsxxx wrote:

Еще вопрос: можно как-то сделать, чтоб 015D: set_gamespeed влияло только на окружающих(на моего актера не влияло) или наоборот? Может для этого нужен какой-то другой опкод? Или мечтать не вредно?))

Мечтать не вредно...гравитацию и время нельзя изменить только для игрока)))

xxxsxxx · 26-07-2008 19:21

В чем здесь ошибка?

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007

{$VERSION 3.1.0027}
{$CLEO .cs}

//-------------MAIN---------------
0000: NOP 
0@ = 304525 
1@ = 304489 

:NONAME_22
wait 0 
if and
   not Actor.Driving($PLAYER_ACTOR)
   Player.Defined($PLAYER_CHAR)
  &0(1@,1i) == 16711680 
  &0(0@,1i) == 16711680 
else_jump @NONAME_22 
Model.Destroy(#BMX)
Model.Load(#BMX)
038B: load_requested_models 
04C4: store_coords_to $4 $5 $6 from_actor $PLAYER_ACTOR with_offset 0.0 5.0 0.0 
$7 = Car.Create(#BMX, $4, $5, $6)
wait 1200 
jump @NONAME_22

Нажимаю "tab"+"/" - все ок. Сажусь в транспорт (любой), выхожу, жму "tab"+"/"- выбивает игру((

3Doomer · 26-07-2008 21:09

После загрузки модели надо поставить проверку на её загруженность в цикле

А опкод выгрузки модели убери из начала и поставь после создания велоса

Alexander · 27-07-2008 07:14

глобальные переменные убери

Soul_Hunter · 27-08-2008 16:34

:NONAME_9
0001: wait 0 ms
0247: load_model #BIKE 
038B: load_requested_models 
00D6: if and
0206:   actor $PLAYER_ACTOR near_car $SKATE radius 5.0 5.0 5.0 flag 0 on_foot 
00E1:   player 0 pressed_key 15 
004D: jump_if_false @NONAME_9 
04ED: load_animation "CHOPPA" 
0407: store_coords_to $X_SKATE $Y_SKATE $Z_SKATE from_car $SKATE with_offset -0.35 -0.6 0.0 
0174: $SKATE_Z = car $SKATE Z_angle 
0009: $SKATE_Z += -90.0 
00A1: put_actor $PLAYER_ACTOR at $X_SKATE $Y_SKATE $Z_SKATE 
0173: set_actor $PLAYER_ACTOR Z_angle_to $SKATE_Z 
0001: wait 1 ms 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_JUMPONR" IFP_file "CHOPPA" 4.0 loopA 0 lockX 0 lockY 0 lockF 1 time -1 // versionB 
0001: wait 2500 ms 
036A: put_actor $PLAYER_ACTOR in_car $SKATE  
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA 0 lockX 0 lockY 0 lockF 1 time -1 // versionB
004F: create_thread @SKATE_MOUVT 

:SKATE_MOUVT
0001: wait 0 ms 
00D6: if 
00DD:   actor $PLAYER_ACTOR driving_car_with_model #BIKE 
004D: jump_if_false @SKATE_MOUVT 
04ED: load_animation "CHOPPA" 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA 0 lockX 0 lockY 0 lockF 1 time -1 // versionB 
03C0: $SKATE = actor $PLAYER_ACTOR car 
004F: create_thread @NONAME_11 

:SKATE_MOUVT_91
03A4: name_thread 'SKATE_MOUVT' 
02E3: $SKATE_S = car $SKATE speed 
004F: create_thread @NONAME_10 
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 1 
004D: jump_if_false @SKATE_MOUVT_201 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 1000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_201
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 1 
004D: jump_if_false @SKATE_MOUVT_276 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 1000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_276
0001: wait 0 ms 
00D6: if and
00E1:   player 0 pressed_key 0 
00E1:   player 0 pressed_key 16 
004D: jump_if_false @SKATE_MOUVT_356 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 10 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_356
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 19 
004D: jump_if_false @SKATE_MOUVT_436 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_DRIVEBYLHS" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 2000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_436
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 6 
004D: jump_if_false @SKATE_MOUVT_510 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_RIDE" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 1 time -1 // versionB 
0001: wait 4000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_510
0001: wait 0 ms 
00D6: if and
00E1:   player 0 pressed_key 16 
0020:   $SKATE_S > 20.0 
004D: jump_if_false @SKATE_MOUVT_596 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_SPRINT" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 1 time -1 // versionB 
0001: wait 4000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_596
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 16 
004D: jump_if_false @SKATE_MOUVT_671 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_PEDAL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 2000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_671
0001: wait 1 ms 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 10 ms 
0002: jump @SKATE_MOUVT_91 

:NONAME_10
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 4 
004D: jump_if_false @NONAME_10 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_BUNNYHOP" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 1000 ms 
0002: jump @NONAME_10 
004E: end_thread 

:NONAME_11
0001: wait 0 ms 
00D6: if 
80DD:   not actor $PLAYER_ACTOR driving_car_with_model #BIKE 
004D: jump_if_false @NONAME_11 
0459: end_thread_named 'SKATE_MOUVT' 
0459: end_thread_named 'SKATE_SPRINT' 
0001: wait 0 ms 
0002: jump @NONAME_9 
0001: wait 0 ms 
004E: end_thread

что не так здесь плззз скажите !!!!я просто подкорректировал скрипт скейта чтобы с миссиями был а то без миссий не катит
вот оригинал:

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 13.10.2007
DEFINE OBJECTS 1
DEFINE OBJECT SANNY BUILDER 3.01      

DEFINE MISSIONS 0

DEFINE EXTERNAL_SCRIPTS 0 // Use -1 in order not to compile AAA script

DEFINE UNKNOWN_EMPTY_SEGMENT 0

DEFINE UNKNOWN_THREADS_MEMORY 0

{$VERSION 3.1.0027}

//-------------MAIN---------------
03A4: name_thread 'MAIN' 
042C: set_total_missions_to 0 
030D: set_max_progress 187 
0997: set_total_respect_points_to 1339 
01F0: set_max_wanted_level_to 6 
0111: set_wasted_busted_check 0 
00C0: set_current_time_hours_to 8 minutes_to 0 
016A: fade 0 time 10 
01B6: set_weather 1 
04BB: select_interior 0 
04E4: unknown_refresh_game_renderer_at 0.0 0.0 
03CB: set_rendering_origin_at 0.0 0.0 0.0 
0053: $PLAYER_CHAR = create_player #NULL at 1504.567 -840.718 67.0 
07AF: $PLAYER_GROUP = player $PLAYER_CHAR group 
01F5: $PLAYER_ACTOR = get_player_actor $PLAYER_CHAR 
0373: set_camera_directly_behind_player 
0173: set_actor $PLAYER_ACTOR Z_angle_to 0.0 
0001: wait 100 ms 
087B: set_player $PLAYER_CHAR clothes_texture "TSHIRTWHITE" model "TSHIRT" body_part 0 
087B: set_player $PLAYER_CHAR clothes_texture "JEANSDENIM" model "JEANS" body_part 2 
087B: set_player $PLAYER_CHAR clothes_texture "SNEAKERBINCBLK" model "SNEAKER" body_part 3 
087B: set_player $PLAYER_CHAR clothes_texture "PLAYER_FACE" model "HEAD" body_part 1 
070D: rebuild_player $PLAYER_CHAR 
016C: restart_if_wasted_at 2027.77 -1420.52 15.99 angle 137.0 town_number 0 
016D: restart_if_busted_at 1550.68 -1675.49 14.51 angle 90.0 town_number 0 
016A: fade 1 time 1000 
0247: load_model #BIKE 
0247: load_model #INFERNUS 
0247: load_model #TEC9 
038B: load_requested_models 
0001: wait 1 ms 
00A5: $SKATE = create_car #BIKE at 1504.567 -842.718 65.9793 
0175: set_car $SKATE Z_angle_to 180.0 
01EB: set_traffic_density_multiplier_to 0.0 
020A: set_car $SKATE door_status_to 4 
004F: create_thread @SKATE_MOUVT 

:MAIN_384
0001: wait 0 ms 
00D6: if and
0206:   actor $PLAYER_ACTOR near_car $SKATE radius 5.0 5.0 5.0 flag 0 on_foot 
00E1:   player 0 pressed_key 15 
004D: jump_if_false @MAIN_384 
04ED: load_animation "CHOPPA" 
0407: store_coords_to $X_SKATE $Y_SKATE $Z_SKATE from_car $SKATE with_offset -0.35 -0.6 0.0 
0174: $SKATE_Z = car $SKATE Z_angle 
0009: $SKATE_Z += -90.0 
00A1: put_actor $PLAYER_ACTOR at $X_SKATE $Y_SKATE $Z_SKATE 
0173: set_actor $PLAYER_ACTOR Z_angle_to $SKATE_Z 
0001: wait 1 ms 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_JUMPONR" IFP_file "CHOPPA" 4.0 loopA 0 lockX 0 lockY 0 lockF 1 time -1 // versionB 
0001: wait 2500 ms 
036A: put_actor $PLAYER_ACTOR in_car $SKATE 
020A: set_car $SKATE door_status_to 0 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA 0 lockX 0 lockY 0 lockF 1 time -1 // versionB 

:SKATE_MOUVT
0001: wait 0 ms 
00D6: if 
00DD:   actor $PLAYER_ACTOR driving_car_with_model #BIKE 
004D: jump_if_false @SKATE_MOUVT 
04ED: load_animation "CHOPPA" 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA 0 lockX 0 lockY 0 lockF 1 time -1 // versionB 
03C0: $SKATE = actor $PLAYER_ACTOR car 
004F: create_thread @SKATE_MOUVT_808 

:SKATE_MOUVT_91
03A4: name_thread 'SKATE_MOUVT' 
02E3: $SKATE_S = car $SKATE speed 
004F: create_thread @SKATE_MOUVT_728 
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 1 
004D: jump_if_false @SKATE_MOUVT_201 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 1000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_201
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 1 
004D: jump_if_false @SKATE_MOUVT_276 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 1000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_276
0001: wait 0 ms 
00D6: if and
00E1:   player 0 pressed_key 0 
00E1:   player 0 pressed_key 16 
004D: jump_if_false @SKATE_MOUVT_356 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 10 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_356
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 19 
004D: jump_if_false @SKATE_MOUVT_436 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_DRIVEBYLHS" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 2000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_436
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 6 
004D: jump_if_false @SKATE_MOUVT_510 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_RIDE" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 1 time -1 // versionB 
0001: wait 4000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_510
0001: wait 0 ms 
00D6: if and
00E1:   player 0 pressed_key 16 
0020:   $SKATE_S > 20.0 
004D: jump_if_false @SKATE_MOUVT_596 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_SPRINT" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 1 time -1 // versionB 
0001: wait 4000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_596
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 16 
004D: jump_if_false @SKATE_MOUVT_671 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_PEDAL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 2000 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_671
0001: wait 1 ms 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_STILL" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 10 ms 
0002: jump @SKATE_MOUVT_91 

:SKATE_MOUVT_728
0001: wait 0 ms 
00D6: if 
00E1:   player 0 pressed_key 4 
004D: jump_if_false @SKATE_MOUVT_728 
0812: AS_actor $PLAYER_ACTOR perform_animation "CHOPPA_BUNNYHOP" IFP_file "CHOPPA" 4.0 loopA -1 lockX 0 lockY 0 lockF 0 time -1 // versionB 
0001: wait 1000 ms 
0002: jump @SKATE_MOUVT_728 
004E: end_thread 

:SKATE_MOUVT_808
0001: wait 0 ms 
00D6: if 
80DD:   not actor $PLAYER_ACTOR driving_car_with_model #BIKE 
004D: jump_if_false @SKATE_MOUVT_808 
0459: end_thread_named 'SKATE_MOUVT' 
0459: end_thread_named 'SKATE_SPRINT' 
0001: wait 0 ms 
0002: jump @MAIN_384 
0001: wait 0 ms 
004E: end_thread

и если кто-то может переделайте в КЛЕО

Last edited by Soul_Hunter (28-08-2008 09:41)

SannyBuilder.com Forums

#1 20-07-2008 07:14

cleo-скрипт. Что не так?

#2 20-07-2008 07:40

Re: cleo-скрипт. Что не так?

#3 20-07-2008 14:46

Re: cleo-скрипт. Что не так?

#4 20-07-2008 14:52

Re: cleo-скрипт. Что не так?

#5 20-07-2008 15:03

Re: cleo-скрипт. Что не так?

#6 20-07-2008 16:19

Re: cleo-скрипт. Что не так?

#7 20-07-2008 16:21

Re: cleo-скрипт. Что не так?

#8 20-07-2008 17:12

Re: cleo-скрипт. Что не так?

#9 20-07-2008 19:00

Re: cleo-скрипт. Что не так?

#10 23-07-2008 22:24

Re: cleo-скрипт. Что не так?

#11 24-07-2008 08:12

Re: cleo-скрипт. Что не так?

#12 25-07-2008 06:15

Re: cleo-скрипт. Что не так?

#13 25-07-2008 08:52

Re: cleo-скрипт. Что не так?

#14 26-07-2008 19:21

Re: cleo-скрипт. Что не так?

#15 26-07-2008 21:09

Re: cleo-скрипт. Что не так?

#16 27-07-2008 07:14

Re: cleo-скрипт. Что не так?

#17 27-08-2008 16:34

Re: cleo-скрипт. Что не так?

Board footer